Одна ККТ для розничного магазина и Интернет-сайта

Публикация № 1183313

Учет и отчетность - Розничная торговля

Опыт использования одной онлайн-кассы для приема платежей в розничном магазине и на Интернет-сайте: технические подробности.

Постановка задачи

Организация занимается розничной торговлей. В розничном магазине используется программа 1С, к которой подключена онлайн-касса. Организация создала Интернет-сайт, на котором есть возможность заказать товар. Необходимо сделать возможность оплатить товар на сайте, при этом чек должен пробиться на кассе, которая установлена в розничном магазине.

 

Что потребовалось для решения

 

1. Какой-то особый кассовый аппарат не требуется. Важно, чтобы кассовый аппарат не имел признака «только для расчетов в сети Интернет». Т.е. этого признака не должно быть в реестре ФНС для данной модели, и этот признак не должен устанавливаться при регистрации ККТ. Другими словами, подойдет любой аппарат для розничной торговли, которой имеет драйвера для 1С. В нашем случае использовался «АТОЛ 22ПТК».

 

2. Для приёма оплаты с помощью банковских карт на сайте потребовался Интернет-эквайринг. В упрощенном виде процесс оплаты состоит из следующих шагов:

а) после оформления заказа в на сайте клиент переадресуется на платёжную форму, где вводит данные своей банковской карты (номер, срок действия и т.д.);

б) далее выполняется запрос авторизации в банк-эквайер и проходит процедура проверки (например, отправка пароля в  SMS-сообщении);

в) при успешной оплате Интернет-эквайер оповещает сайт.

г) сайт оповещает клиента об успешной оплате заказа.

В нашем случае использовался Интернет-эквайринг от Сбербанка.

 

3. Потребовалась доработка конфигурации 1С. Можно использовать любою конфигурацию, которая поддерживает розничную торговлю и торговое оборудование (Розница, УТ, КА, УНФ и т.д). В нашем случае использовалась конфигурация УТ10.3, в которую был добавлен http-сервис для интеграции с сайтом.

 

4. Так как http-сервис в 1С работает в контексте "сервера", а работа с торговым оборудованием в 1С  осуществляется в контексте "клиента", была использована вспомогательная программа «Модуль ККТ: онлайн-касса по сети» (//xn---1-6kca8bgsjrjhe.xn--p1ai/public/1109732/). Эта программа позволяет подключать онлайн-кассу к службе "Сервер ККТ", а 1С может подключаться к этой службе через драйвер "Клиент ККТ" как в контексте "клиента", так и в контексте "сервера". Получилась следующая схема:

 

Кассовые смены

Так как Интернет-сайт не зависит от графика работы магазина, то потребовалось внести изменения в процесс открытия и закрытия кассовых смен.

1. Открытие смены

Смену открывает кассир в магазине или Интернет-сайт, в зависимости от того, кто раньше регистрирует оплату.

В начале рабочего дня кассир проверяет статус кассовой смены. Если смена не открыта, то кассир открывает смену. С другой стороны, сайт перед каждым приёмом оплаты тоже проверяет статус кассовой смены и, при необходимости, открывает смену.

2. Закрытие смены

По окончании рабочего дня кассир закрывает смену. Сайт перед каждым приёмом оплаты проверяет статус кассовой смены. Если смена закрыта, открывает смену. В конце суток, по расписанию (например, в 23:55), сайт проверяет статус смены. Если смена открыта, то сайт закрывает смену.

 

Доработки в 1С

Работа с ККТ внутри http-сервиса осуществляется с помощью драйвера "Клиент ККТ". Так как http-сервис работает в контексте "сервера", то этот драйвер (файл KKT_Client_3001.zip) нужно поместить в общий макет типа "Двоичные данные".

Для подключения драйвера используется вспомогательная функция ПодготовитьККТ:


Функция ПодготовитьККТ(Отказ,ОписаниеОшибки)
	
	Результат = Новый Структура;
	
	КассаККМ = Константы.ИнтернетМагазин_КассаККМ.Получить(); //добавили константу, где указываем ККМ для сайта
	Если ЗначениеЗаполнено(КассаККМ)=Ложь Тогда
		Отказ = Истина;
		ОписаниеОшибки = "Не указана касса ККМ для Интернет-платежей!";
		Возврат Результат;
	КонецЕсли;
	
	П = Константы.ИнтернетМагазин_СерверККТ.Получить(); //добавили константу, где храним настройки подключания к серверу ККТ в виде Сервер:Порт. Здесь Сервер - имя компьютера, к которому подключен кассовый аппарат. Порт по умолчанию 52111

	Если ЗначениеЗаполнено(П)=Ложь Тогда
		Отказ = Истина;
		ОписаниеОшибки = "Не указаны параметры сервера ККТ";
		Возврат Результат;
	КонецЕсли;

	х = Найти(П,":");
	Если х=0 Тогда
		Сервер = П;
		Порт = 52111;
	Иначе
		Сервер = Лев(П,х-1);
		Попытка
			Порт = Число(Сред(П,х+1));
		Исключение
			Порт = 52111;
		КонецПопытки;
	КонецЕсли;
	
	Если ПодключитьВнешнююКомпоненту("ОбщийМакет.KKT_Client_3001","ZY312",ТипВнешнейКомпоненты.Native)<>Истина Тогда
		Отказ = Истина;
		ОписаниеОшибки = "Ошибка подключения внешней компоненты";
		Возврат Результат;
	КонецЕсли;

	Компонента = Новый("AddIn.ZY312.MKClient_3001");
	Компонента.УстановитьПараметр("Server",Сервер);
	Компонента.УстановитьПараметр("Port",Порт);
	

	ИДУстройства = "";
	Если Компонента.Подключить(ИДУстройства)<>Истина Тогда
		Отказ = Истина;
		П1 = "";
		Компонента.ПолучитьОшибку(П1);
		ОписаниеОшибки  = "Ошибка открытия ККТ "+П1;
		Возврат Результат;
	КонецЕсли;
	
	Результат.Вставить("КассаККМ",КассаККМ);
	Результат.Вставить("Драйвер",Компонента);
	Результат.Вставить("ИДУстройства",ИДУстройства);
	Результат.Вставить("ПараметрыРегистрации",Новый Структура);
	Результат.Вставить("РевизияИнтерфейса",3001);
	
	Возврат Результат;
КонецФункции

 

Получение статуса кассовой смены:


Функция ПолучитьТекущееСостояниеКассовойСмены(Отказ,ОписаниеОшибки)
	
	ПараметрыПодключения = ПодготовитьККТ(Отказ,ОписаниеОшибки);
	Если Отказ Тогда
		Ответ = Новый Структура("Error",ОписаниеОшибки);
		Возврат Значение_В_JSON(Ответ);
	КонецЕсли;
	
	ВходныеПараметры = ""+Символы.ПС+"";
	
	ВыходныеПараметры = "";
	Если ПараметрыПодключения.Драйвер.ПолучитьТекущееСостояние(ПараметрыПодключения.ИДУстройства,ВходныеПараметры,ВыходныеПараметры)<>Истина Тогда
		П1 = "";
		ПараметрыПодключения.Драйвер.ПолучитьОшибку(П1);
		Ответ.Text = "Ошибка вызова метода GetCurrentStatus "+П1;
		
		ПараметрыПодключения.Драйвер.Отключить(ПараметрыПодключения.ИДУстройства);

		Отказ = Истина;
		Ответ = Новый Структура("Error","Ошибка вызова метода ПолучитьТекущееСостояние: "+П1);
		Возврат Значение_В_JSON(Ответ);
	КонецЕсли;

	ПараметрыПодключения.Драйвер.Отключить(ПараметрыПодключения.ИДУстройства);
	
	П = ПолучитьВыходныеПараметрыИзXML(ВыходныеПараметры);
	
	Если ЗначениеЗаполнено(П.СостояниеСмены) Тогда
		Ответ = Новый Структура("ShiftState",П.СостояниеСмены);
	Иначе
		Отказ = Истина;
		Ответ = Новый Структура("Error","Не удалось определить состояние кассовой смены: "+ВыходныеПараметры);
	КонецЕсли;
	
	Возврат Значение_В_JSON(Ответ);
КонецФункции

Функция ПолучитьВыходныеПараметрыИзXML(XML)

	Результат = Новый Структура("СостояниеСмены,НомерСмены");
	
	ЧтениеXML = Новый ЧтениеXML; 
	ЧтениеXML.УстановитьСтроку(XML);
	ЧтениеXML.ПерейтиКСодержимому();
	
	Если ЧтениеXML.Имя="OutputParameters" И ЧтениеXML.ТипУзла=ТипУзлаXML.НачалоЭлемента Тогда
		Если ЧтениеXML.Прочитать() И ЧтениеXML.Имя="Parameters" И ЧтениеXML.ТипУзла=ТипУзлаXML.НачалоЭлемента Тогда

			ShiftState = СокрЛП(ЧтениеXML.ЗначениеАтрибута("ShiftState"));
			Если ShiftState="1" Тогда
				Результат.СостояниеСмены = "Закрыта";

			ИначеЕсли ShiftState="2" Тогда
				Результат.СостояниеСмены = "Открыта";

			ИначеЕсли ShiftState="3" Тогда
				Результат.СостояниеСмены = "Истекла";
			КонецЕсли;
			
			ShiftNumber = СокрЛП(ЧтениеXML.ЗначениеАтрибута("ShiftNumber"));
			Попытка
				Результат.НомерСмены = Число(ShiftNumber);
			Исключение
			КонецПопытки;

		КонецЕсли;
	КонецЕсли;

	Возврат Результат;
КонецФункции

Функция Значение_В_JSON(Структура)
	ЗаписьJSON = Новый ЗаписьJSON;
	ЗаписьJSON.УстановитьСтроку();
	ЗаписатьJSON(ЗаписьJSON, Структура);
	СтрJSON = ЗаписьJSON.Закрыть();	
	
	Возврат СтрJSON;
КонецФункции

 

Открытие и закрытие кассовой смены:


Функция ОткрытьКассовуюСмену(JSON,Отказ,ОписаниеОшибки)

	ПараметрыПодключения = ПодготовитьККТ(Отказ,ОписаниеОшибки);
	Если Отказ Тогда
		Ответ = Новый Структура("Error",ОписаниеОшибки);
		Возврат Значение_В_JSON(Ответ);
	КонецЕсли;

	ВходныеПараметры = ""+Символы.ПС+"";
	
	ВыходныеПараметры = "";
	Если ПараметрыПодключения.Драйвер.ОткрытьСмену(ПараметрыПодключения.ИДУстройства,ВходныеПараметры,ВыходныеПараметры)<>Истина Тогда
		П1 = "";
		ПараметрыПодключения.Драйвер.ПолучитьОшибку(П1);
		
		ПараметрыПодключения.Драйвер.Отключить(ПараметрыПодключения.ИДУстройства);

		Отказ = Истина;
		Ответ = Новый Структура("Error","Ошибка вызова метода ОткрытьСмену "+П1);
		Возврат Значение_В_JSON(Ответ);
	КонецЕсли;

	ПараметрыПодключения.Драйвер.Отключить(ПараметрыПодключения.ИДУстройства);
	
	П = ПолучитьВыходныеПараметрыИзXML(ВыходныеПараметры);
	
	Если ЗначениеЗаполнено(П.НомерСмены) Тогда
		Ответ = Новый Структура;
		Ответ.Вставить("ShiftNumber",П.НомерСмены);
	Иначе
		Отказ = Истина;
		Ответ = Новый Структура("Error","Не удалось определить номер кассовой смены: "+ВыходныеПараметры);
		Возврат Значение_В_JSON(Ответ);
	КонецЕсли;
	
	
	//Создаем документ КассоваяСмена
	Док = Документы.КассоваяСмена.СоздатьДокумент();
	Док.Дата = ТекущаяДатаСеанса();
	Док.НачалоКассовойСмены = Док.Дата;
	Док.КассаККМ = ПараметрыПодключения.КассаККМ;
	Док.Организация = Док.КассаККМ.Владелец;
	Док.Статус = Перечисления.СтатусыКассовойСмены.Открыта;
	Док.НомерСменыККТ = П.НомерСмены;
	Попытка
		Док.Записать(РежимЗаписиДокумента.Проведение);
	Исключение
		Отказ = Истина;
		Ответ = Новый Структура("Error",ОписаниеОшибки());
		Возврат Значение_В_JSON(Ответ);
	КонецПопытки;

	Возврат Значение_В_JSON(Ответ);
КонецФункции

Функция ЗакрытьКассовуюСмену(JSON,Отказ,ОписаниеОшибки)
	
	ПараметрыПодключения = ПодготовитьККТ(Отказ,ОписаниеОшибки);
	Если Отказ Тогда
		Ответ = Новый Структура("Error",ОписаниеОшибки);
		Возврат Значение_В_JSON(Ответ);
	КонецЕсли;

	ВходныеПараметры = ""+Символы.ПС+"";
	
	ВыходныеПараметры = "";
	Если ПараметрыПодключения.Драйвер.ЗакрытьСмену(ПараметрыПодключения.ИДУстройства,ВходныеПараметры,ВыходныеПараметры)<>Истина Тогда
		П1 = "";
		ПараметрыПодключения.Драйвер.ПолучитьОшибку(П1);
		
		ПараметрыПодключения.Драйвер.Отключить(ПараметрыПодключения.ИДУстройства);

		Отказ = Истина;
		Ответ = Новый Структура("Error","Ошибка вызова метода ЗакрытьСмену "+П1);
		Возврат Значение_В_JSON(Ответ);
	КонецЕсли;

	ПараметрыПодключения.Драйвер.Отключить(ПараметрыПодключения.ИДУстройства);
	
	П = ПолучитьВыходныеПараметрыИзXML(ВыходныеПараметры);
	
	Если ЗначениеЗаполнено(П.НомерСмены) Тогда
		Ответ = Новый Структура;
		Ответ.Вставить("ShiftNumber",П.НомерСмены);
	Иначе
		Отказ = Истина;
		Ответ = Новый Структура("Error","Не удалось определить номер кассовой смены: "+ВыходныеПараметры);
		Возврат Значение_В_JSON(Ответ);
	КонецЕсли;
	
	
	Запрос = Новый Запрос(
	"ВЫБРАТЬ ПЕРВЫЕ 1
	|	Док.Ссылка,
	|	Док.НачалоКассовойСмены КАК НачалоКассовойСмены
	|ИЗ
	|	Документ.КассоваяСмена КАК Док
	|ГДЕ
	|	Док.КассаККМ = &КассаККМ
	|	И Док.Проведен = ИСТИНА
	|	И Док.Статус = ЗНАЧЕНИЕ(Перечисление.СтатусыКассовойСмены.Открыта)
	|
	|УПОРЯДОЧИТЬ ПО
	|	НачалоКассовойСмены УБЫВ");
	Запрос.УстановитьПараметр("КассаККМ",ПараметрыПодключения.КассаККМ);
	Табл = Запрос.Выполнить().Выгрузить();
	Если Табл.Количество()=1 Тогда
		Док = Табл[0].Ссылка.ПолучитьОбъект();
		Док.ОкончаниеКассовойСмены = ТекущаяДата();
		Док.Статус = Перечисления.СтатусыКассовойСмены.Закрыта;
		Попытка
			Док.Записать(РежимЗаписиДокумента.Проведение);
		Исключение
			Отказ = Истина;
			Ответ = Новый Структура("Error",ОписаниеОшибки());
			Возврат Значение_В_JSON(Ответ);
		КонецПопытки;
	КонецЕсли;

	Возврат Значение_В_JSON(Ответ);
КонецФункции

 

Пробитие чека:


Функция ПробитьЧекНаККТ(JSON,Отказ,ОписаниеОшибки)
	
	Попытка
		А = ОбщегоНазначения.JSON_В_Значение(JSON);
		ИД = СокрЛП(А.doc);
	Исключение
		Отказ = Истина;
		Ответ = Новый Структура("Error","Ошибка разбора JSON");
		Возврат Значение_В_JSON(Ответ);
	КонецПопытки;
	
	ПараметрыПодключения = ПодготовитьККТ(Отказ,ОписаниеОшибки);
	Если Отказ Тогда
		Ответ = Новый Структура("Error",ОписаниеОшибки);
		Возврат Значение_В_JSON(Ответ);
	КонецЕсли;

    //Предполагается, что сайт уже выгрузил заказ в документ ЧекККМ. Нам остатось провести документ и пробить чек.
	Ссылка = Документы.ЧекККМ.ПолучитьСсылку(Новый УникальныйИдентификатор(ИД));
	Док = Ссылка.ПолучитьОбъект();
	
	Попытка
		Док.Записать(РежимЗаписиДокумента.Проведение,РежимПроведенияДокумента.Оперативный);
	Исключение
		Отказ = Истина;
		Ответ = Новый Структура("Error",ОписаниеОшибки());
		Возврат Значение_В_JSON(Ответ);
	КонецПопытки;
	
	XMLПакет = КакойТоОбщийМодуль.ПолучитьXMLПакетДляФискализацияЧека(...); //вызвать функцию общего модуля, в зависимости от конфигурации
	Электронно = Истина;
	ВыходныеПараметры = Неопределено;

	Если ПараметрыПодключения.Драйвер.СформироватьЧек(ПараметрыПодключения.ИДУстройства, Электронно, XMLПакет, ВыходныеПараметры)<>Истина Тогда
		П1 = "";
		ПараметрыПодключения.Драйвер.ПолучитьОшибку(П1);
		
		ПараметрыПодключения.Драйвер.Отключить(ПараметрыПодключения.ИДУстройства);
		
		//распроведем документ
		Попытка
			Док.Записать(РежимЗаписиДокумента.ОтменаПроведения);
		Исключение
		КонецПопытки;
		
		Отказ = Истина;
		Ответ = Новый Структура("Error","Ошибка вызова метода СформироватьЧек: "+П1);
		Возврат Значение_В_JSON(Ответ);
	КонецЕсли;
	
	ЧтениеXML = Новый ЧтениеXML;
	ЧтениеXML.УстановитьСтроку(ВыходныеПараметры);
	Д = ФабрикаXDTO.ПрочитатьXML(ЧтениеXML);
	НомерСмены = Число(Д.Parameters.ShiftNumber);
	НомерЧека = Число(Д.Parameters.CheckNumber);    //Номер фискального документа    (ФД)
	ФискальныйПризнак = Д.Parameters.FiscalSign;    //Фискальный признак             (ФПД)
			
	//Получим номер ФН
	НомерФН = "";
	ТаблицаПараметровККТ = "";
	Если ПараметрыПодключения.Драйвер.ПолучитьПараметрыККТ(ПараметрыПодключения.ИДУстройства,ТаблицаПараметровККТ)=Истина Тогда
		Попытка
			ЧтениеXML = Новый ЧтениеXML;
			ЧтениеXML.УстановитьСтроку(ТаблицаПараметровККТ);
			Д = ФабрикаXDTO.ПрочитатьXML(ЧтениеXML);
			НомерФН = Д.FNSerialNumber;
		Исключение
		КонецПопытки;
	КонецЕсли;
	
	ПараметрыПодключения.Драйвер.Отключить(ПараметрыПодключения.ИДУстройства);

	Ответ = Новый Структура;
	Ответ.Вставить("FNSerialNumber",НомерФН);
	Ответ.Вставить("CheckNumber",НомерЧека);
	Ответ.Вставить("FiscalSign",ФискальныйПризнак);
	
	Значение_В_JSON(Ответ);
КонецФункции

Функция JSON_В_Значение(Значение)
	ЧтениеJSON = Новый ЧтениеJSON;
    ЧтениеJSON.УстановитьСтроку(Значение);
    Результат = ПрочитатьJSON(ЧтениеJSON);
    ЧтениеJSON.Закрыть();

	Возврат Результат;
КонецФункции

 

Обратите внимание на параметр "Электронно = Истина", т.е. бумажный чек не распечатается, но в налоговую чек уйдет.

Если чек успешно пробит, то функция ПробитьЧекНаККТ возвращает номер фискального документа, фискальный признак и номер фискального накопителя. Эти параметры можно использовать для составления ссылки на электронный чек. В нашем случае, для "Платформа ОФД", ссылка выглядит следующим образом:

https://lk.platformaofd.ru/web/noauth/cheque?fn=9251433377086452&fp=4493881571&i=7803

где fn - номер фискального накопителя

      fp - фискальный признак

      i - номер фискального документа

 

Как это выглядит для посетителя сайта

1. Посетитель сайта набрал товар в корзину. На сайте сделана кнопка "Оплатить":

2. Посетитель переадресуется на платёжную форму, где вводит данные своей банковской карты:

 

3. Выполняется запрос авторизации в банк-эквайер и проходит процедура проверки:

 

4. Посетителю отправляется ссылка на электронный чек:

 

P.S. Юридические и экономические аспекты выходят за рамки данной статьи.

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. DanDy 16 23.01.20 14:17 Сейчас в теме
Если бы вы использовали web-сервис от компании атол (идет в составе 10 драйверов) и например вот эту обработку обслуживания
https://infostart.ru/public/942924/ то обошлись бы только изменением в области контроля открытой смены.
5. Terve!R 27.01.20 19:22 Сейчас в теме
(1) а как вот эта обработка принимает чеки с сайта? Где подробная инструкция по настройке, как сделано в этой статье?
Просто сказать "используйте web-сервис от компании атол" много ума не надо.
6. DanDy 16 28.01.20 09:39 Сейчас в теме
(5) Просто прочитать заголовок много ума не надо.
Читайте лучше, обработка предназначена для работы из 1С с кассой Атол по web-сервису.
В документации к 10 драйверу есть вся инфа, которой более чем достаточно, чтобы прописать формирование JSON-а и отправить его POST-запросом куда требуется (непосредственно с сайта). Интеграцию с сайтом ТС всё равно дописывал как я понял из статьи.
7. Terve!R 28.01.20 12:35 Сейчас в теме
(6)
работа с ККТ Атол ведется через HTTP-запросы к WEB-серверу АТОЛ

Это обработка работает через Web-серевер Атола, получается надо тоже самое писать для сайта, тогда зачем мне эта обработка? Зачем давать непонятные ссылки, чтобы человек еще там что-то сам писал на сайте? Я и сам знаю, что надо писать код, чтобы все заработало, что за советы такие "бери читай документацию и пиши"? Я просил готовое решение, а не посылание в документацию или Гугл, а готового решения для сайта для работы с Атолом по ссылке нет.
8. DanDy 16 28.01.20 14:08 Сейчас в теме
(7) я писал комментарий к статье. Где и у кого вы просили готовое решение понятия не имею, в связи с чем ваша претензия должна быть направлена к самому себе. У меня готовых решений вы не просили.
А обработка избавила бы автора статьи от реализации собственно НТТР-сервиса на 1С.
9. DanDy 16 28.01.20 14:08 Сейчас в теме
(7) Предлагаю вам сначала думать, а потом писать и жаловаться на комментарии, а то выглядите как маленький троль
2. Rustig 1346 24.01.20 12:57 Сейчас в теме
спасибо за подробное описание! уникальный опыт!
3. Sergynia 1 25.01.20 14:15 Сейчас в теме
Огромное спасибо за статью.
4. sivin-alexey 257 25.01.20 14:32 Сейчас в теме
Жмите "+", если понравилась
Оставьте свое сообщение

См. также

Как продавать маркируемый товар (обувь) из 1С:Розница + сканер для маркировки

Статья no Архив с данными v8 Розница Легкая промышленность, мода и одежда Россия Акцизы Бесплатно (free) Розничная торговля Сканер штрих-кода

Маркировка обуви в нашей стране началась с 1 июля 2019 года. Но если в 2019м году от участников рынка требовалось только зарегистрироваться в системе «Честный знак», то теперь уже совсем не за горами дата, когда необходимо будет в обязательном порядке передавать данные о проданных единицах обуви. По графику этот судный день назначен на 1 марта 2020 года. Как все знают, русский человек всегда надеется на лучшее (или на авось, кому как нравится), надеется что правительство передумает. Сейчас в сети ходит информация о возможных сроках переноса судного дня на 1 июля, или, даже, 1 сентября 2020 года, это лишь отсрочки, но никак не отмена обязательной маркировки. В дополнении ко всему вышесказанному надо отметить, что самая популярная программа для розничной торговли, а именно 1С:Розница, как и ее пользователи не смогла заранее подготовиться к нововведениям. Обновление, в котором система стала работать более-менее корректно, вышло лишь 6 февраля 2020 года (менее чем за месяц до судного дня)

22.02.2020    395    VCPro    6       

Голосование за доклады на INFOSTART MEETUP Kazan - до 25 февраля. Промо

Выбирайте и голосуйте за самые интересные доклады! Лучшие из лучших попадут в окончательную программу казанского митапа. Оставить свой голос можно до 25 февраля 2020 года.

Подключение АТОЛ 91/92Ф к 1С:Касса

Статья Системный администратор Нет файла v8 1cv8.cf Россия Кассовые операции Бесплатно (free) ККМ

Т.к. я не нашел данной информации в гугле (возможно, плохо искал), решил, что нужно оставить эту статью здесь, может, поможет кому.

10.09.2019    4004    rule_2    4       

Онлайн-курс "Подготовка к экзамену 1С:Эксперт и 1С:Профессионал по технологическим вопросам" с 7 по 24 апреля 2020 г. Промо

На курсе вы получите практические навыки решения задач производительности 1С, в том числе характерных для высоконагруженных информационных систем (более 1000 пользователей). Подготовка к экзамену – только одна из составляющих курса. 70% слушателей приходят за знаниями, которые позволят расти и зарабатывать, делать сложные задачи на крупных проектах.

16450 рублей

Решение проблем с сетевым ключом защиты для Штрих-М: Торговое предприятие 5

Статья Системный администратор Программист Нет файла v8 1cv8.cf Розничная и сетевая торговля (FMCG) Россия УУ Windows Розничная торговля Бесплатно (free) Администрирование данных 1С

Штрих-М: Торговое предприятие 5 имеет свой ключ защиты, который проверяет сразу после запуска базы. Если вы увидели сообщение "ключ не найден", материал в этой статье может помочь решить вашу проблему.

21.08.2019    3583    Van2507    0       

​​​​​​​CorelDRAW Graphics Suite 2019 Промо

CorelDRAW – пакет профессиональных инструментов для редактирования фотографий, разработки дизайна, создания макетов страниц и векторных иллюстраций

Вывод отчетов из Штрих-М Торговое предприятие 5 на кассовое ПО Кассир 5 через веб-сервис

Статья Системный администратор Программист Нет файла v8 1cv8.cf Розничная и сетевая торговля (FMCG) Россия УУ Windows Розничная торговля Бесплатно (free) WEB

Универсальный механизм вывода отчетов товароучетной системы Штрих-М Торговое предприятие в кассовое ПО Кассир 5 посредством веб-сервиса.

14.08.2019    3048    Van2507    1       

Готовые переносы данных из различных конфигураций 1C Промо

Рекомендуем готовые решения для переноса данных из различных конфигураций 1C. C техподдержкой от разработчиков и гарантией от Инфостарт.

Чеки ККМ для расчетов с ИП по безналу. Новые обязательные реквизиты в чеке

Статья Программист Нет файла v8 v8::ОУ УТ11 УУ Windows Оптовая торговля Бесплатно (free) Практика программирования ККМ Разработка

Новые требования законодательства по пробитию чеков ККМ при расчетах с индивидуальными предпринимателями по безналу. Нюансы подключения интеграционной компоненты ДТО 10.5.0 на примере кассы ККТ АТОЛ 11Ф и конфигурации 1С УТ 11.4. Необходимые доработки типовой конфигурации УТ 11.4 для вывода на печать новых обязательных реквизитов: покупатель, ИНН, ГТД, страна происхождения.

22.07.2019    10126    ids79    16       

Маркировка табака. Формирование тега 1162 "код товара" для передачи в ККТ и ОФД

Статья Программист Нет файла v8 1cv8.cf Розничная и сетевая торговля (FMCG) Россия Розничная торговля Бесплатно (free) Практика программирования Разработка

С 01.07.2019 стартует новый этап маркировки сигарет. Теперь в кассе обязательно надо будет считывать марку с пачек табака, если она там есть. Считывать и передавать в ОФД через тег 1162 в онлайн-кассе. А как сформировать данные этого тега? Не все так просто...

27.06.2019    6373    kirlog    32       

Сдача регламентированной отчетности из программ 1С Промо

Сдача регламентированной отчетности из программ "1С" во все контролирующие органы без выгрузок и загрузок в другие программы. Для групп компаний действуют специальные предложения.

от 1500 руб.

Система питания в офисе: как совместить вендинговые автоматы, 1С, облачную кассу и веб-технологии

Статья Руководитель проекта Нет файла v8 1cv8.cf Розничная и сетевая торговля (FMCG) Россия УУ Розничная торговля Бесплатно (free) Интеграция

В начале 2019 года тенденция развития автоматов питания в России привела к появлению проекта нового формата питания на работе — МикроМаркета “Го!Поедим”. Потребовалось создать новый формат зоны питания сотрудников: интегрировать в офисные кухни полноценные МикроМаркеты с бесконтактной оплатой, кофе-машинами, лаунж-зоной. Если правильно совместить вендинговые автоматы, облачную кассу, 1С и веб-технологии, то в результате будут не только сытые сотрудники, но и корректная работа всей системы офисного питания.

22.06.2019    3533    antonovintervolga    6       

1С и компьютерное зрение: новый подход к контролю за ассортиментом магазина

Статья Бизнес-аналитик Нет файла v8 1С:Франчайзи, автоматизация бизнеса УУ Розничная торговля Бесплатно (free) Внешние источники данных

Машинное зрение в магазинах и 1С. Как поднять эффективность торгового предприятия (магазин. кафе, шоурум и т.д.) с совершенно неожиданной стороны? Как получить реальные демографические данные покупателей и, самое главное, как это использовать в повседневной работе магазина? Как можно расширить привычные ABC и XYZ анализ, добавив в них пласт данных о трафике и демографии покупателей? Что необходимо для 1С, чтобы использовать данные видеоанализа людского трафика?

20.06.2019    5929    osipov_cvizi    16       

Управление ИТ-проектами. Модуль 2: продвинутый онлайн-курс по классическим методам управления проектами. Вебинары проходят с 12 марта по 11 июня 2020 года. Промо

Продвинутый онлайн-курс по классическому управлению ИТ-проектами позволит слушателям освоить инструменты из PMBoK® и 1С:Технологии корпоративного внедрения и научиться их применять для проектов любого масштаба. Курс включает в себя 12 вебинаров и 12 видеолекции, разбор кейсов и рекомендации экспертов по проектам слушателей. Ведущая курса - Мария Темчина.

от 13000 рублей

Сжатие данных в мобильном приложении 1С:Предприятие

Статья Программист Нет файла v8 v8::Mobile 1cv8.cf УУ Розничная торговля Бесплатно (free) Мобильная разработка

Эту небольшую статью я планировал опубликовать у себя на сайте, чтобы такие любители мобильного приложения от 1С:Предприятие, как я, могли использовать её без дополнительно потраченных двух дней на поиски вариантов написания алгоритма. Во-первых, хотел сказать, что я небольшой разработчик, который начинал делать свои первые шаги ещё на заре правления "Семерки". Новая платформа версии 8 была как глоток свежего воздуха - бодрящий и легко воспринимаемый организмом. Я был очень удивлен, да что сказать, до сих пор удивляюсь как элементарные вещи можно делать на 1С, и как это стремно делается на других языках программирования. Во-вторых, обилие разнообразных интерпретаций платформы позволяет развернуться на все 360 градусов, захватив своими проектами, наверное, любые ветки бизнеса. Так вот, о небольшом нюансе работы с новой мобильной платформой я и хотел рассказать... Сам додумался, так сказать.

27.05.2019    10334    yarsort    27       

Подборка программ для взаимодействия с ЕГАИС Промо

ЕГАИС (Единая государственная автоматизированная информационная система) - автоматизированная система, предназначенная для государственного контроля за объёмом производства и оборота этилового спирта, алкогольной и спиртосодержащей продукции. Инфостарт рекомендует подборку проверенных решений для взаимодействия с системой.

Рассрочка в Рознице 2.2

Статья Программист Нет файла v8 Розница УУ Розничная торговля Бесплатно (free) Практика программирования Разработка

Добавляем Рассрочку в документ "Отчет о розничных продажах" в конфигурации "Розница для Беларуси, редакция 2.2."

15.04.2019    2573    borlog    0       

Подборка решений для взаимодействия со ФГИС «Меркурий» Промо

С 1 июля 2019 года все компании, участвующие в обороте товаров животного происхождения, должны перейти на электронную ветеринарную сертификацию (ЭВС) через ФГИС «Меркурий». Инфостарт предлагает подборку программ, связанных с этим изменением.

Новый раздел на Инфостарте - Electronic Software Distribution Промо

Инфостарт напоминает: на нашем сайте можно купить не только ПО, связанное с 1С. В нашем арсенале – ESD-лицензии на ПО от ведущих вендоров: Microsoft, Kaspersky, ESET, Dr.Web, Аскон и другие.

  • Низкие цены, без скрытых платежей и наценок
  • Оперативная отгрузка
  • Возможность оплаты с личного счета (кешбек, обмен стартмани на рубли и т.п.)
  • Покупки идут в накопления для получения скидочных карт лояльности Silver (5%) и Gold (10%)

Расширение конструктора мобильного рабочего места для варианта "клиент 1С+RDP" (для любых wi-fi терминалов). Экосистема решений Simple WMS

Статья Программист Бизнес-аналитик Руководитель проекта Нет файла v8::УФ УУ Производство готовой продукции (работ, услуг) Розничная торговля Учет ОС и НМА Учет ТМЦ Бесплатно (free) Инструментарий разработчика Сканер штрих-кода Терминал сбора данных Универсальные функции Мобильная разработка

Развитие проекта «Конструктор мобильного клиента на Android» https://infostart.ru/public/976636/ для устройств не на Андроиде (работающих в режиме RDP). В отличие от варианта Android работа на терминалах происходит в режиме 1С:Предприятие через RDP а конфигурации мобильных клиентов полностью совместимы для обоих версий. Т.е. конфигурация единая, создается один раз и ее может читать как Android -устройство, так и 1С-клиент на RDP без необходимости какой либо переделки.

05.02.2019    8650    informa1555    5       

Весы Штрих-СЛИМ, Штрих-ПРИНТ и 1С: Розница 2.2.11.ХХ

Статья Системный администратор Нет файла v8 Розница Розничная и сетевая торговля (FMCG) Россия Windows Розничная торговля Бесплатно (free) Весы

Как установить драйвер весов по протоколу POS2 или драйвер ШТРИХ-М:Весы с печатью этикеток ШТРИХ-ПРИНТ на Windows 7 и выше.

29.01.2019    7207    Newdjeen    11       

Базовый курс по обмену данными в системе 1С:Предприятие. Онлайн-интенсив с 12 по 28 мая 2020 г. Промо

Данный онлайн-курс предусматривает изучение механизмов платформы “1С:Предприятие”, обеспечивающих обмен данными между различными прикладными 1С-решениями и взаимодействие с другими информационными системами. Курс предназначен для тех, кто уже имеет определенные навыки конфигурирования и программирования в системе “1С:Предприятие”.

5500 рублей

Работа с кассой Atol через веб-сервер ДТО-10

Статья Программист Нет файла v8 Россия Кассовые операции НДС Бесплатно (free) Внешние источники данных ККМ Фискальный регистратор

Поддержка многопользовательской печати на одном устройстве ККТ. Поддержка изменений в законодательстве (Переход на ФФД 1.05 и НДС 20%).

31.12.2018    23957    medangel    41       

1C:Предприятие для программистов: Запросы и отчеты. Второй поток. Онлайн-интенсив с 17 марта по 16 апреля 2020 г. Промо

Данный онлайн-курс предусматривает углубленное изучение языка запросов и возможностей системы компоновки данных, которые понадобятся при разработке отчетов, работающих на платформе “1С:Предприятие” в рамках различных прикладных решений. Курс предназначен для тех, кто уже имеет определенные навыки конфигурирования и программирования в системе “1С:Предприятие”, а также для опытных пользователей различных прикладных решений, которые используют в своей работе отчеты разного назначения.

6500 рублей

Редактирование цены в РМК. 1С: УТ 11

Статья Программист Нет файла v8 УТ11 Россия Розничная торговля Бесплатно (free) Практика программирования

В типовой конфигурации УТ 11 нет возможности в режиме РМК изменить цену на товар, хотя такая необходимость появляется довольно часто. Внеся небольшие изменения в конфигурацию, можно добиться нужной функциональности. Использовался релиз 1С УТ 11.4.5.135 на платформе 1С:Предприятие 8.3 (8.3.13.1513).

26.12.2018    5366    Stæg    8       

INFOSTART MEETUP Kazan. 13 марта 2020 г. Промо

Инфостарт продолжает путешествие по России. Следующая остановка - Казань. Тема мероприятия - управление и технологии автоматизации учета на платформе "1С: Предприятие". Ждем всех: докладчиков и участников! Стоимость участия - 5 500 рублей. Цена действительна до 30.01.2020

5 500

Прикладной пример переработки стандартной формы РМК - Розница

Статья Программист Нет файла v8 Розница УУ Кассовые операции Розничная торговля Бесплатно (free) Работа с интерфейсом

Простой пример, как с помощью программного изменения шрифтов элементов формы достичь наилучшего результата отображения на примере формы РМК.

04.10.2018    14387    asdfgcom    58